Dim line As Integer

' Dumps the properties of all the files within the given path into the current worksheet
Sub StartMp3Processing()
    line = 2

    dumpFileProperties "[PATH_TO_YOUR_MP3_ROOT_FOLDER]"
End Sub

Function UpdateMp3(file, field, oldValue, newValue)
    If file <> "Full Path" Then
        exe = "[PATH_TO_TAG_BINARY]\TagUpdate.exe"

        Shell exe & " " & SurroundWithQuotes(file) & " " & _
                            SurroundWithQuotes(field) & " " & _
                            SurroundWithQuotes(oldValue) & " " & _
                            SurroundWithQuotes(newValue)
    End If
End Function

' TODO: enhance this - e.g. strip existing quotes with \
Function SurroundWithQuotes(value)
    SurroundWithQuotes = Chr(34) & value & Chr(34)
End Function

' Recusively dumps specific properties of files present within the given path
Function dumpFileProperties(pathToAnalyse)

    ' List of the properties ID we want to dump
    ' A full list of available properties is available in the comments of
    ' http://msdn.microsoft.com/en-us/library/windows/desktop/bb787870(v=vs.85).aspx
    propertiesIdList = Array(0, 13, 14, 15, 16, 20, 21, 26, 27, 28)
    
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.Namespace(pathToAnalyse)
    
    For Each strFileName In objFolder.Items
        If strFileName.isFolder Then
            dumpFileProperties strFileName
        ' Uncomment this line and comment the other Else if you want to restrict the dump...
        'ElseIf objFolder.getDetailsOf(strFileName, 2) = "VLC media file (.mp3)" Or objFolder.getDetailsOf(strFileName, 2) = "VLC media file (.wav)" Then
        Else
            ' Dump the full file path in the first column
            ActiveSheet.Cells(line, 1) = strFileName.Path
            
            col = 2
            For Each propId In propertiesIdList
                ActiveSheet.Cells(line, col) = objFolder.getDetailsOf(strFileName, propId)
                col = col + 1
            Next
            line = line + 1

        End If
    Next
End Function